cmake_minimum_required(VERSION 3.8)
project(lbot_arm_driver)

if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()

# find dependencies
find_package(ament_cmake REQUIRED)
find_package(rclcpp REQUIRED)
find_package(std_msgs REQUIRED)
find_package(msgs REQUIRED)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

set(LBOT_SDK_DIR "${CMAKE_CURRENT_SOURCE_DIR}/C++")
set(LBOT_SDK_INCLUDE_DIR "${LBOT_SDK_DIR}/include")

if(CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64" OR CMAKE_SYSTEM_PROCESSOR MATCHES "AMD64")
  set(LBOT_TARGET_ARCH "linux_x64")
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "aarch64" OR CMAKE_SYSTEM_PROCESSOR MATCHES "arm64")
  set(LBOT_TARGET_ARCH "linux_arm64")
else()
  set(LBOT_TARGET_ARCH "linux_x64")
endif()

set(LBOT_SDK_LIB_DIR "${LBOT_SDK_DIR}/libs/linux/${LBOT_TARGET_ARCH}")
find_library(LBOT_API_CPP_LIBRARY NAMES lbot_api_cpp PATHS "${LBOT_SDK_LIB_DIR}" REQUIRED)

add_executable(arm_drivers src/arm_drivers.cpp)
target_include_directories(arm_drivers PRIVATE
  "${CMAKE_CURRENT_SOURCE_DIR}/include"
  "${LBOT_SDK_INCLUDE_DIR}"
)
target_link_libraries(arm_drivers "${LBOT_API_CPP_LIBRARY}")
ament_target_dependencies(arm_drivers rclcpp std_msgs msgs)

set_target_properties(arm_drivers PROPERTIES
  BUILD_RPATH "${LBOT_SDK_LIB_DIR}"
  INSTALL_RPATH "$ORIGIN"
)

install(TARGETS arm_drivers
  DESTINATION lib/${PROJECT_NAME}
)

install(FILES
  "${LBOT_SDK_LIB_DIR}/liblbot_api_cpp.so"
  "${LBOT_SDK_LIB_DIR}/liblbot_api_cpp.so.1"
  "${LBOT_SDK_LIB_DIR}/liblbot_api_cpp.so.1.0.5"
  DESTINATION lib/${PROJECT_NAME}
)

if(BUILD_TESTING)
  find_package(ament_lint_auto REQUIRED)
  # the following line skips the linter which checks for copyrights
  # comment the line when a copyright and license is added to all source files
  set(ament_cmake_copyright_FOUND TRUE)
  # the following line skips cpplint (only works in a git repo)
  # comment the line when this package is in a git repo and when
  # a copyright and license is added to all source files
  set(ament_cmake_cpplint_FOUND TRUE)
  ament_lint_auto_find_test_dependencies()
endif()

ament_package()
